Multiple PREP_PROCESS_VARs

[laura_albrecht_automic]

Hi.  I'm fairly good at scripting, but nested PREP_PROCESS_VARs I find confusing.   :/

I am trying to implement a process that I can run via a time event every 15 minutes checking the status of agents.  If an agent is down - I want to automatically restart it.  

However, I also want the ability to have an exception list.  For example, I might be doing maintenance on a server and I don't want that agent to be restarted every 15 minutes.  

So that's my scenario.

But  I'm having problems with the fact that I'm comparing one variable (list of all agents) to the contents of another variable (list of agents to ignore).  I'm sure this is a simple fix, but I've been working on this most of yesterday afternoon and this morning and tried a variety of things and I just can't get this to work.

Or let me rephrase - my current code works fine IF I only have 1 entry in my exception list.  If I have multiple - it doesn't work.

Any scripting gurus out there have time to take a look at this?

! *************************************************************************************

! ***                                                                               ***

! ***  This routine is used to check for agents that are down and restart them.     ***

! ***                                                                               ***

! *************************************************************************************

! 

! Get a dynamic list of agents by querying the database.

! 

:SET &HNDA# = PREP_PROCESS_VAR(SYSTEM.X.LIST_OF_AGENTS.VARA.X)

:PROCESS &HNDA#

! 

! Check to see if the agent is up or down

! 

:  SET &AGENT_NAMEA# = GET_PROCESS_LINE(&HNDA#, 2)

:  SET &FOUND# = ''

:  IF SYS_HOST_ALIVE(&AGENT_NAMEA#)= 'Y'

:    PRINT '&AGENT_NAMEA# is alive!'

:  ELSE

! 

! Need to check if the down agent is on the exclusion list.

! 

:    PRINT ''

:    PRINT '&AGENT_NAMEA# appears to be down!'

:    SET &HNDB# = PREP_PROCESS_VAR(ESP.MONITORING.AGENT_EXCEPTION_LIST.VARA.X)

!

! There will always be an entry in the Exception List variable so that it enters the 

! PREP_PROCESS_VAR loop.

!

:    PROCESS &HNDB#

:      SET &FOUND# = GET_PROCESS_LINE(&HNDB#, 1)

!

! If it finds the dummy entry do nothing.

!

:      IF &FOUND# = 'DO NOT REMOVE'

:      ELSE

:        PRINT '&FOUND# seems to be from the exception list variable.'

:      ENDIF

!

! If the entry on the exception list matches one of the down agents then no

! restart will be done.

!

:      IF &FOUND# = &AGENT_NAMEA#

:        PRINT 'Since &AGENT_NAMEA# is on the exception list - we will not attempt to restart it.'

:        PRINT ''

:      ELSE

!

! If it finds the dummy entry do nothing.

!

:        IF &FOUND# = 'DO NOT REMOVE'

!

! If it is not on the exception list - then attempt to restart it.

!

:        ELSE

:          PRINT ''

:          PRINT '&AGENT_NAMEA# is down - attempting to restart.'

:          PRINT ''

:          SET &AGENT_TYPE# = GET_PROCESS_LINE(&HNDA#, 5)

:          SET &SERVICE_MGR_NAME# = GET_PROCESS_LINE(&HNDA#, 4)

:          IF &AGENT_TYPE# <> 'WINDOWS' OR 'UNIX'

:            SET &AGENT_NAMEA# = GET_VAR(SYSTEM.X.AGENT_SERVER_INFO.VARA.X, '&AGENT_NAMEA#', 2)

:          ENDIF

:          PUBLISH &AGENT_NAMEA#, , TASK

:          PUBLISH &AGENT_TYPE#, , TASK

:          PUBLISH &SERVICE_MGR_NAME#, , TASK

:          SET &ALIAS# = 'ESP.MONITORING.AGENT_STATUS_&AGENT_NAMEA#.JOBS.U'

:          SET &ACTOBJ# = ACTIVATE_UC_OBJECT(ESP.MONITORING.AGENT_RESTART.JOBS.U, , , , , PASS_VALUES, , &ALIAS#)

:        ENDIF

:      ENDIF

:    ENDPROCESS

:    CLOSE_PROCESS &HNDB#

:  ENDIF

:ENDPROCESS

:CLOSE_PROCESS &HNDA#

[Leonard Olteanu]

How about using EXECUTE_ON_END, EXECUTE_ON_LOST and EXECUTE_ON_START in Client 0 instead of polling every 15 minutes?

https://us.v-cdn.net/5019921/uploads/editor/pl/6pypxv8xdymp.png" width="627">

[Legacy User]

Hi Laura,
I'll try this at my end and get back to you soon.
BR,
Antoine

[Legacy User]

Could you post a screenshot of the ESP.MONITORING.AGENT_EXCEPTION_LIST.VARA.X object's content?

[Legacy User]

I would also need a screenshot of SYSTEM.X.AGENT_SERVER_INFO.VARA.X .

BR,
Antoine

[laura_albrecht_automic]

I had to create the AGENT_SERVER_INFO variable because my RA agents don't have the server names as the agent names.  I posted something else on how to find that out, but this was best I could do for now.

https://us.v-cdn.net/5019921/uploads/editor/h3/hh87jblwqbg4.png" width="948">

[Anon Anon]

Laura:

A cursory view of the logic ensuring that all of the IF/ELSE/ENDIF sets are "closed" as are the PREP_PROCESS_VAR sets, looks good to me.  I have occasionally encountered situations where a missing ENDIF was not detected and I got spurious and difficult to diagnose results.

If it were me, I'd use the Execute once dialog and trace the activation protocol to see the logic path being executed.  Also I might place some type of debug statements, such as PRINT statements or a loop counter of some type to see how many times that the inner process is executed and what it finds with each keyword and value.

For what it's worth we have a small number of PREP_PROCESS_VAR pieces of logic that are nested, similar to yours, under our V8 system and they operate properly.

Good luck and if I think of anything else I'll chime in again.

[Anon Anon]

Another suggestion - maybe easier :-)

What about using a VARA.MULTI object for Agent exclusion?

 

I did a short example, created a VARA.SQLi listing ALL defined agents ignoring limitations in HACL for other clients):

select * from OH

where oh_otype='HOST'

and oh_idnr >100000

 

and a static VARA containing my Agents to exclude: WIN03 and WIN04 (black circle)

 

Both VARAs are source of my VARA.multi - Difference (red circle)

 

 

here the screenshot:
https://us.v-cdn.net/5019921/uploads/editor/dg/ffw99w76u6d7.png" width="1166">

All Agents of my Clt1 system overview in blue.

Possibly that helps.

[Legacy User]

Hello,

Just two general hints:

•  A sql select of current objects should always have an „oh_deleteflag = 0“in it. So it should look like:

 

select * from OH

where oh_otype='HOST'

and oh_idnr > 100000

and oh_deleteflag = 0

 

 

• Another way to get all Agents of a system by PREP_PROCESS_VAR is:

:set &hnd# = PREP_PROCESS_VAR(UC_EX_HOSTCHAR,,) :process &hnd# :  set &Agent_Name# = GET_PROCESS_LINE(&hnd#,1) :  print &Agent_Name# :endprocess

KR, Josef

[Anon Anon]

and oh_deleteflag = 0

..oops forgotten ..
THX Josef :-)


[laura_albrecht_automic]

FrankMuffke  - thank you SOO much!  What a wonderful idea!  I am still trying to have new functionality like this come to mind when I run into challenges like this.  Using the MULTI variable worked amazingly well.  I cut down my code considerably.

:SET &HNDA# = PREP_PROCESS_VAR(ESP.MONITORING.EXCLUDE_AGENTS_ON_EXCEPTION_LIST.VARA.X)

:PROCESS &HNDA#

:  SET &AGENT_NAMEA# = GET_PROCESS_LINE(&HNDA#,2)

:  IF SYS_HOST_ALIVE(&AGENT_NAMEA#)= 'Y'

:    PRINT '&AGENT_NAMEA# is alive!'

:  ELSE

:    PRINT ''

:    PRINT '&AGENT_NAMEA# is down - attempting to restart.'

:    PRINT ''

:    SET &AGENT_TYPE# = GET_PROCESS_LINE(&HNDA#,5)

:    SET &SERVICE_MGR_NAME# = GET_PROCESS_LINE(&HNDA#,4)

:    IF &AGENT_TYPE# <> 'WINDOWS' OR 'UNIX'

:      SET &AGENT_NAMEA# = GET_VAR(SYSTEM.X.AGENT_SERVER_INFO.VARA.X,'&AGENT_NAMEA#',2)

:    ENDIF

:    PUBLISH &AGENT_NAMEA#,,TASK

:    PUBLISH &AGENT_TYPE#,,TASK

:    PUBLISH &SERVICE_MGR_NAME#,,TASK

:    SET &ALIAS#  = 'ESP.MONITORING.RESTART_DOWN_AGENT_&AGENT_NAMEA#.JOBS.U'

:    SET &ACTOBJ# = ACTIVATE_UC_OBJECT(ESP.MONITORING.RESTART_DOWN_AGENT.JOBS.U,,,,,PASS_VALUES, , &ALIAS#)

:  ENDIF

:ENDPROCESS

:CLOSE_PROCESS &HNDA#

Thanks for everyone's ideas / help!

[Anon Anon]

No problem - great that it works well now :-)

[laura_albrecht_automic]

Is this something you think I should attach as an export?  Or put in the Marketplace?  I know there is an Agent Restarter process there, but mine is slightly different - it restarts ALL down agents (minus the ones on the exception list).  The other one gives you the option to select which ones.  Both have their uses.  I wasn't sure if anyone would be interested in mine though.  If anyone is - let me know.

[Anon Anon]

Possibly I would be great adding an XML export of it to this thread.
(Including AE Version :-) )