Chicago Endpoint Management User Group

I noticed that your VBScript calls Outlook to send the email. It is a small but very well written and effective way of sending an email.
There is also another way to send an email using VBScript without using Outlook (or any mail program). It contains a tad bit more code but does the job just the same. This approach is not dependent on whether or not Outlook is installed on the machine. I use this code extensively throughout various VBScripts to send myself emails.
The only caveat is that you will have to specify a username and password in the VBScript. In my case I requested to have a user account created that has the ability to send emails but CANNOT log into a machine locally and does not have any administrative rights whatsoever. This account is only used to send emails through various VBScripts.
VBScript Code Follows:

Dim EmailMessage, ObjMessage
EmailMessage = "Put Your Email Message Here"
SendEmail EmailMessage
WScript.Quit
Sub SendEmail(EmailMessage)
	Const cdoSendUsingPickup = 1 'Send message using the local SMTP service pickup directory. 
	Const cdoSendUsingPort = 2 'Send the message using the network (SMTP over the network). 
	Const cdoAnonymous = 0 'Do not authenticate
	Const cdoBasic = 1 'basic (clear-text) authentication
	Const cdoNTLM = 2 'NTLM
	Set objMessage = CreateObject("CDO.Message") 
	objMessage.Subject = "Put Email Subject Here"
	objMessage.From = "Put Email From Address Here"
	objMessage.To = "Put Email To Address Here"
	objMessage.TextBody = EMailMessage
	'==This section provides the configuration information for the remote SMTP server.
	objMessage.Configuration.Fields.Item _
	("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2 
	'Name or IP of Remote SMTP Server
	objMessage.Configuration.Fields.Item _
	("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "Put Name Or IP Of Email Server Here"
	'Type of authentication, NONE, Basic (Base64 encoded), NTLM
	objMessage.Configuration.Fields.Item _
	("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = cdoBasic
	'Your UserID on the SMTP server
	objMessage.Configuration.Fields.Item _
	("http://schemas.microsoft.com/cdo/configuration/sendusername") = "Put Name Of User Account Here"
	'Your password on the SMTP server
	objMessage.Configuration.Fields.Item _
	("http://schemas.microsoft.com/cdo/configuration/sendpassword") = "Put Password Of User Account Here"
	'Server port (typically 25)
	objMessage.Configuration.Fields.Item _
	("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25 
	'Use SSL for the connection (False or True)
	objMessage.Configuration.Fields.Item _
	("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = False
	'Connection Timeout in seconds (the maximum time CDO will try to establish a connection to the SMTP server)
	objMessage.Configuration.Fields.Item _
	("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 60
	objMessage.Configuration.Fields.Update
	'==End remote SMTP server configuration section==
	objMessage.Send
	Set ObjMessage = Nothing
End Sub